Anillo 3 - Original
An interactive fiction by Mel Hython (2009) - the Inform 7 source text
Contents
Previous
Next
Complete text
Section 0 - Posibles jugadores
[ CLASE JUGADOR: una clase de persona, simplemente ]
A posible jugador is a kind of patroller.
The drive of a posible jugador is usually 50. [ se mueven la mitad de las veces]
The frequency of a posible jugador is usually 1. [pero se plantea cada turno]
A posible jugador is usually aimless. [y se mueven de forma aleatoria]
[no hay puertas pero por si acaso]
The openingcapability of a posible jugador is usually unlockedonly.
the reclosingcapability of a posible jugador is usually leave.
[Tienen un cadaver]
A posible jugador have a thing called el cadaver.
Instead of telling a patroller about something, try asking noun about it.
Instead of answering a patroller that something, try asking noun about it.
Instead of asking a patroller for something, try asking noun about it.
Instead of asking a patroller about something:
if the noun is icalante:
say "Veamos: 'uh, uuuh, uh?'";
bnw;
say "Nada, no se entera de nada. No debo hablar correctamente el simio.";
otherwise if the noun is an orco:
say "Uhm... 'Vrek, verk, vrke?'.";
bnw;
say "Nada, ni caso. ¡Qué asco de lengua!";
otherwise:
say "¡Bah! Los seres inferiores no hablan.".
[ FUNCIÓN para obtener el potencial jugador más cercano]
To decide what posible jugador is the jugador mas proximo:
let jmp be the player;
let nmjmp be 100;
repeat with pj running through posible jugador:
if pj is the player:
next;
if pj is in NoLugar:
next;
if pj is icalante and (icalante is enfadado or icalante is preso):
next;
let nm be number of moves from the location to the location of pj;
[say "[pj] a [nm].";]
if nm is less than nmjmp and nm is greater than -1:
now nmjmp is nm;
now jmp is pj;
decide on jmp.
[TO SAY: para expresar el portador ]
To say el portador:
if the player is:
-- nuhur: say "Nuhur";
-- icalante: say "el icalante";
-- zhur: say "Zhur";
-- berg: say "Berg";
-- yerk: say "Yerk".
[Every turn:
say "Siguiente jugador: [jugador mas proximo]".]
[CLASE ORCO: una subclase de posible jugador ]
An orco is a kind of posible jugador.
An orco has a number called buscando. The buscando of an orco is 0.
Understand "orco" as orco.
[Sus objetos se ven]
Rule for deciding the concealed possessions of a orco: no.
[Lo que llevan encima]
After printing the name of a orco (called ello) while listing contents:
if ello carries anything:
say " (llevando [a list of things carried by ello])".